-- I) Base case
open BASE-NSLPK
-- check
  red inv11(init,p,n,m1) .
close

-- II) Inductive cases

--> 1) sdm1(s,p10,q10,r10)
--> c-sdm1(s,p10,q10,r10),
--> ~(m1 = m1(p10,p10,q10,enc1(q10,n(p10,q10,r10),p10)))
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op r10 : -> Random .
-- assumptions
  -- eq c-sdm1(s,p10,q10,r10) = true .
  eq r10 \in rands(s) = false .
  --
  eq (m1 = m1(p10,p10,q10,enc1(q10,n(p10,q10,r10),p10))) = false .
-- successor state
  eq s' = sdm1(s,p10,q10,r10) .
-- check 
  red istep11 .
close
--> c-sdm1(s,p10,q10,r10),
--> m1 = m1(p10,p10,q10,enc1(q10,n(p10,q10,r10),p10)),
--> ~(enc1(p,n,intruder) = enc1(q10,n(p10,q10,r10),p10))
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op r10 : -> Random .
-- assumptions
  -- eq c-sdm1(s,p10,q10,r10) = true .
  eq r10 \in rands(s) = false .
  --
  eq m1 = m1(p10,p10,q10,enc1(q10,n(p10,q10,r10),p10)) .
  eq (enc1(p,n,intruder) = enc1(q10,n(p10,q10,r10),p10)) = false .
-- successor state
  eq s' = sdm1(s,p10,q10,r10) .
-- check 
  red istep11 .
close
--> c-sdm1(s,p10,q10,r10),
--> m1 = m1(p10,p10,q10,enc1(q10,n(p10,q10,r10),p10)),
--> enc1(p,n,intruder) = enc1(q10,n(p10,q10,r10),p10)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op r10 : -> Random .
-- assumptions
  -- eq c-sdm1(s,p10,q10,r10) = true .
  eq r10 \in rands(s) = false .
  --
  eq m1 = m1(p10,p10,q10,enc1(q10,n(p10,q10,r10),p10)) .
  -- eq enc1(p,n,intruder) = enc1(q10,n(p10,q10,r10),p10) .
  eq p = q10 .
  eq n = n(p10,q10,r10) .
  eq p10 = intruder .
  --
-- successor state
  eq s' = sdm1(s,p10,q10,r10) .
-- check 
  red istep11 .
close
--> ~c-sdm1(s,p10,q10,r10)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op r10 : -> Random .
-- assumptions
  eq c-sdm1(s,p10,q10,r10) = false .
-- successor state
  eq s' = sdm1(s,p10,q10,r10) .
-- check 
  red istep11 .
close

--> 2) sdm2(s,q10?,p10,q10,r10,n10)
--> c-sdm2(s,q10?,p10,q10,r10,n10)
open ISTEP-NSLPK
-- fresh constants
  ops q10? p10 q10 : -> Principal .
  op r10 : -> Random .
  op n10 : -> Nonce .
  op nw10 : -> Network .
-- assumptions
  -- eq c-sdm2(s,q10?,p10,q10,r10,n10) = true .
  eq network(s) = m1(q10?,q10,p10,enc1(p10,n10,q10)) nw10 .
  eq r10 \in rands(s) = false .
  --
-- successor state
  eq s' = sdm2(s,q10?,p10,q10,r10,n10) .
-- check 
  red istep11 .
close
--> ~c-sdm2(s,q10?,p10,q10,r10,n10)
open ISTEP-NSLPK
-- fresh constants
  ops q10? p10 q10 : -> Principal .
  op r10 : -> Random .
  op n10 : -> Nonce .
-- assumptions
  eq c-sdm2(s,q10?,p10,q10,r10,n10) = false .
-- successor state
  eq s' = sdm2(s,q10?,p10,q10,r10,n10) .
-- check 
  red istep11 .
close

--> 3) sdm3(s,q10?,p10,q10,n10,n20)
--> c-sdm3(s,q10?,p10,q10,n10,n20)
open ISTEP-NSLPK
-- fresh constants
  ops q10? p10 q10 : -> Principal .
  ops n10 n20 : -> Nonce .
  op nw10 : -> Network .
-- assumptions
  -- eq c-sdm3(s,q10?,p10,q10,n10,n20) = true .
  eq network(s) = m1(p10,p10,q10,enc1(q10,n10,p10))
                  m2(q10?,q10,p10,enc2(p10,n10,n20,q10)) nw10 .
  --
-- successor state
  eq s' = sdm3(s,q10?,p10,q10,n10,n20) .
-- check 
  red istep11 .
close
--> ~c-sdm3(s,q10?,p10,q10,n10,n20)
open ISTEP-NSLPK
-- fresh constants
  ops q10? p10 q10 : -> Principal .
  ops n10 n20 : -> Nonce .
-- assumptions
  eq c-sdm3(s,q10?,p10,q10,n10,n20) = false .
-- successor state
  eq s' = sdm3(s,q10?,p10,q10,n10,n20) .
-- check 
  red istep11 .
close

--> 4) fkm11(s,p10,q10,m10)
--> c-fkm11(s,p10,q10,m10),
--> ~(m1 = m1(intruder,p10,q10,cipher1(m10)))
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m10 : -> Message1 .
  op nw10 : -> Network .
-- assumptions
  -- eq c-fkm11(s,p10,q10,m10) = true .
  eq network(s) = m10 nw10 .
  --
  eq (m1 = m1(intruder,p10,q10,cipher1(m10))) = false .
-- successor state
  eq s' = fkm11(s,p10,q10,m10) .
-- check 
  red istep11 .
close
--> c-fkm11(s,p10,q10,m10),
--> m1 = m1(intruder,p10,q10,cipher1(m10)), ~(cipher1(m10) = enc1(p,n,intruder))
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m10 : -> Message1 .
  op nw10 : -> Network .
-- assumptions
  -- eq c-fkm11(s,p10,q10,m10) = true .
  eq network(s) = m10 nw10 .
  --
  eq m1 = m1(intruder,p10,q10,cipher1(m10)) .
  eq (cipher1(m10) = enc1(p,n,intruder)) = false .
-- successor state
  eq s' = fkm11(s,p10,q10,m10) .
-- check 
  red istep11 .
close
--> c-fkm11(s,p10,q10,m10),
--> m1 = m1(intruder,p10,q10,cipher1(m10)), cipher1(m10) = enc1(p,n,intruder)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m10 : -> Message1 .
  op nw10 : -> Network .
-- assumptions
  -- eq c-fkm11(s,p10,q10,m10) = true .
  eq network(s) = m10 nw10 .
  --
  eq m1 = m1(intruder,p10,q10,cipher1(m10)) .
  eq cipher1(m10) = enc1(p,n,intruder) .
-- successor state
  eq s' = fkm11(s,p10,q10,m10) .
-- check 
  red inv11(s,p,n,m10) implies istep11 .
close
--> ~c-fkm11(s,p10,q10,m10)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m10 : -> Message1 .
-- assumptions
  eq c-fkm11(s,p10,q10,m10) = false .
-- successor state
  eq s' = fkm11(s,p10,q10,m10) .
-- check 
  red istep11 .
close

--> 5) fkm12(s,p10,q10,n10)
--> c-fkm12(s,p10,q10,n10),
--> ~(m1 = m1(intruder,p10,q10,enc1(q10,n10,p10)))
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op n10 : -> Nonce .
  op ns10 : -> NonceSoup .
-- assumptions
  -- eq c-fkm12(s,p10,q10,n10) = true .
  eq nonces(s) = n10 ns10 .
  --
  eq (m1 = m1(intruder,p10,q10,enc1(q10,n10,p10))) = false .
-- successor state
  eq s' = fkm12(s,p10,q10,n10) .
-- check 
  red istep11 .
close
--> c-fkm12(s,p10,q10,n10),
--> m1 = m1(intruder,p10,q10,enc1(q10,n10,p10)),
--> ~(enc1(q10,n10,p10) = enc1(p,n,intruder))
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op n10 : -> Nonce .
  op ns10 : -> NonceSoup .
-- assumptions
  -- eq c-fkm12(s,p10,q10,n10) = true .
  eq nonces(s) = n10 ns10 .
  --
  eq m1 = m1(intruder,p10,q10,enc1(q10,n10,p10)) .
  eq (enc1(q10,n10,p10) = enc1(p,n,intruder)) = false .
-- successor state
  eq s' = fkm12(s,p10,q10,n10) .
-- check 
  red istep11 .
close
--> c-fkm12(s,p10,q10,n10),
--> m1 = m1(intruder,p10,q10,enc1(q10,n10,p10)),
--> enc1(q10,n10,p10) = enc1(p,n,intruder)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op n10 : -> Nonce .
  op ns10 : -> NonceSoup .
-- assumptions
  -- eq c-fkm12(s,p10,q10,n10) = true .
  eq nonces(s) = n10 ns10 .
  --
  eq m1 = m1(intruder,p10,q10,enc1(q10,n10,p10)) .
  -- eq enc1(q10,n10,p10) = enc1(p,n,intruder) .
  eq q10 = p .
  eq n10 = n .
  eq p10 = intruder .
  --
-- successor state
  eq s' = fkm12(s,p10,q10,n10) .
-- check 
  red inv5(s,n) implies istep11 .
close
--> ~c-fkm12(s,p10,q10,n10)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op n10 : -> Nonce .
-- assumptions
  eq c-fkm12(s,p10,q10,n10) = false .
-- successor state
  eq s' = fkm12(s,p10,q10,n10) .
-- check 
  red istep11 .
close

--> 6) fkm21(s,p10,q10,m20)
--> c-fkm21(s,p10,q10,m20)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m20 : -> Message2 .
  op nw10 : -> Network .
-- assumptions
  -- eq c-fkm21(s,p10,q10,m20) = true .
  eq network(s) = m20 nw10 .
  --
-- successor state
  eq s' = fkm21(s,p10,q10,m20) .
-- check 
  red istep11 .
close
--> ~c-fkm21(s,p10,q10,m20)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m20 : -> Message2 .
-- assumptions
  eq c-fkm21(s,p10,q10,m20) = false .
-- successor state
  eq s' = fkm21(s,p10,q10,m20) .
-- check 
  red istep11 .
close

--> 7) fkm22(s,p10,q10,n10,n20)
--> c-fkm22(s,p10,q10,n10,n20)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  ops n10 n20 : -> Nonce .
  op ns10 : -> NonceSoup .
-- assumptions
  -- eq c-fkm22(s,p10,q10,n10,n20) = true .
  eq nonces(s) = n10 n20 ns10 .
  eq (n10 = n20) = false .
  --
-- successor state
  eq s' = fkm22(s,p10,q10,n10,n20) .
-- check 
  red istep11 .
close
--> ~c-fkm22(s,p10,q10,n10,n20)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  ops n10 n20 : -> Nonce .
-- assumptions
  eq c-fkm22(s,p10,q10,n10,n20) = false .
-- successor state
  eq s' = fkm22(s,p10,q10,n10,n20) .
-- check 
  red istep11 .
close

--> 8) fkm31(s,p10,q10,m30)
--> c-fkm31(s,p10,q10,m30)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m30 : -> Message3 .
  op nw10 : -> Network .
-- assumptions
  -- eq c-fkm31(s,p10,q10,m30) = true .
  eq network(s) = m30 nw10 .
  --
-- successor state
  eq s' = fkm31(s,p10,q10,m30) .
-- check 
  red istep11 .
close
--> ~c-fkm31(s,p10,q10,m30)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op m30 : -> Message3 .
-- assumptions
  eq c-fkm31(s,p10,q10,m30) = false .
-- successor state
  eq s' = fkm31(s,p10,q10,m30) .
-- check 
  red istep11 .
close

--> 9) fkm32(s,p10,q10,n10)
--> c-fkm32(s,p10,q10,n10)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op n10 : -> Nonce .
  op ns10 : -> NonceSoup .
-- assumptions
  -- eq c-fkm32(s,p10,q10,n10) = true .
  eq nonces(s) = n10 ns10 .
  --
-- successor state
  eq s' = fkm32(s,p10,q10,n10) .
-- check 
  red istep11 .
close
--> ~c-fkm32(s,p10,q10,n10)
open ISTEP-NSLPK
-- fresh constants
  ops p10 q10 : -> Principal .
  op n10 : -> Nonce .
-- assumptions
  eq c-fkm32(s,p10,q10,n10) = false .
-- successor state
  eq s' = fkm32(s,p10,q10,n10) .
-- check 
  red istep11 .
close

-- Q.E.D.